Даем названия переменным: как префиксы экономят наше время

//**************************************************************************
// Назначение : загрузить контрагентов, имеющих хоть что-нибудь в поле ИНН *
// проверить справочник на дубли контрагентов *
// Параметры : Печатная форма. *
// Если не передана, то отчет будет выведен в новое окно *
// Возвращает : Истина, если контрагенты не имеют дублей *
// Ложь , если есть задвоенные ИНН *
//**************************************************************************
Функция ПроверитьКонтрагентовНаУникальностьИНН(тдЭлементФормы=Неопределено) Экспорт
// Проверка необходимых параметров перед началом печати отчета
Если спрОрганизация.Пустая() Тогда
Сообщить("Выберите организацию перед проверкой контрагентов !");
Возврат Ложь;
КонецЕсли;
// Определяем макет отчета
мкКонтрагенты=ПолучитьМакет("Контрагенты");
обЗаголовок =мкКонтрагенты.ПолучитьОбласть("Заголовок");
обШапка =мкКонтрагенты.ПолучитьОбласть("Шапка");
обГруппировка=мкКонтрагенты.ПолучитьОбласть("ГруппировкаКонтрагент");
обСтрока =мкКонтрагенты.ПолучитьОбласть("Строка");
// Задаем табличный документ
Если НЕ(тдЭлементФормы=Неопределено) Тогда
// Такое условие задано специально : чтобы в исходном тексте можно было обращаться к свойствам переменной "тдКонтрагенты"
тдКонтрагенты=тдЭлементФормы;
Иначе
тдКонтрагенты=Новый ТабличныйДокумент;
КонецЕсли;
тдКонтрагенты.Очистить();
тдКонтрагенты.РазмерКолонтитулаСверху=9;
тдКонтрагенты.РазмерКолонтитулаСнизу =9;
тдКонтрагенты.ОриентацияСтраницы =ОриентацияСтраницы.Портрет;
тдКонтрагенты.АвтоМасштаб =Истина;
тдКонтрагенты.ПолеСлева =20;
тдКонтрагенты.ПолеСправа =10;
тдКонтрагенты.ПолеСверху =10;
тдКонтрагенты.ПолеСнизу =10;
тдКонтрагенты.ФиксацияСверху = 7;
тдКонтрагенты.ОтображатьЗаголовки=Ложь;
тдКонтрагенты.ОтображатьСетку =Ложь;
тдКонтрагенты.Защита =Ложь;
тдКонтрагенты.ТолькоПросмотр =Истина;
// Выводим заголовок и шапку отчета
обЗаголовок.Параметры.ОрганизацияИмя=СокрЛП(спрОрганизация.НаименованиеПолное);
обЗаголовок.Параметры.ОрганизацияИНН=СокрЛП(спрОрганизация.ИНН);
обЗаголовок.Параметры.ОрганизацияКПП=СокрЛП(спрОрганизация.КПП);
обЗаголовок.ВерхнийКолонтитул.ТекстСлева="Организация : "+СокрЛП(спрОрганизация.НаименованиеПолное)+", ИНН:"+СокрЛП(спрОрганизация.ИНН)+", КПП:"+СокрЛП(спрОрганизация.КПП)+".";
обЗаголовок.ВерхнийКолонтитул.Выводить=Истина;
обЗаголовок.ВерхнийКолонтитул.НачальнаяСтраница=2;
тдКонтрагенты.Вывести(обЗаголовок);
тдКонтрагенты.ПовторятьПриПечатиСтроки=тдКонтрагенты.Вывести(обШапка);
// Начинаем формировать запрос к исходным данным
нЗадвоенийВсего=0;
лУникальностьПоИНН=Истина;
зпКонтрагенты=Новый Запрос;
зпКонтрагенты.УстановитьПараметр("ПустаяСтрока","");
зпКонтрагенты.Текст="ВЫБРАТЬ РАЗРЕШЕННЫЕ

Контрагенты.Ссылка КАК КонтрагентСсылка,

Контрагенты.Наименование КАК Имя,

Контрагенты.ИНН КАК ИНН,

Контрагенты.КПП КАК КПП,

Контрагенты.Код КАК Код,

1 КАК КоличествоРаз

ИЗ

Справочник.Контрагенты КАК Контрагенты

ГДЕ

Контрагенты.ЭтоГруппа = ЛОЖЬ

И Контрагенты.ИНН <> &ПустаяСтрока



УПОРЯДОЧИТЬ ПО

ИНН,

КПП,

Код

ИТОГИ

СУММА(КоличествоРаз)

ПО

ИНН,

КПП,

Код";
впКонтрагенты=зпКонтрагенты.Выполнить();
Сообщить("Запрос к базе по контрагентам выполнен !");
вбКонтрагентыИНН=впКонтрагенты.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам,"ИНН");
Пока вбКонтрагентыИНН.Следующий() Цикл
сИНН=вбКонтрагентыИНН.ИНН;
Сообщить(сИНН);
Если СтрДлина(сИНН)<10 Тогда
Продолжить;
КонецЕсли;
вбКонтрагентыКПП=вбКонтрагентыИНН.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам,"КПП");
Пока вбКонтрагентыКПП.Следующий() Цикл
Сообщить(сИНН+" "+вбКонтрагентыКПП.КПП);
Если вбКонтрагентыКПП.КоличествоРаз>1 Тогда
Если тдЭлементФормы=Неопределено Тогда
Сообщить("Контрагент с ИНН "+СокрЛП(вбКонтрагентыКПП.ИНН)+?(ПустаяСтрока(вбКонтрагентыКПП.КПП),""," и КПП "+СокрЛП(вбКонтрагентыКПП.КПП))+" встречается "+Строка(вбКонтрагентыКПП.КоличествоРаз)+" раз");
КонецЕсли;
лУникальностьПоИНН=Ложь;
нЗадвоенийВсего=нЗадвоенийВсего+1;
обГруппировка.Параметры.НомерПоБазе=Строка(нЗадвоенийВсего)+".";
обГруппировка.Параметры.Заполнить(вбКонтрагентыКПП);
тдКонтрагенты.Вывести(обГруппировка);
нКонтрагент=0;
вбКонтрагентКод=вбКонтрагентыКПП.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам,"Код");
тдКонтрагенты.НачатьГруппуСтрок();
Пока вбКонтрагентКод.Следующий() Цикл
вбКонтрагентСсылка=вбКонтрагентКод.Выбрать();
Пока вбКонтрагентСсылка.Следующий() Цикл
Сообщить(сИНН+" "+вбКонтрагентыКПП.КПП+" "+вбКонтрагентКод.Имя);
нКонтрагент=нКонтрагент+1;
обСтрока.Параметры.НомерПоКонтрагенту=Строка(нКонтрагент)+")";
обСтрока.Параметры.Заполнить(вбКонтрагентСсылка);
тдКонтрагенты.Вывести(обСтрока);
КонецЦикла;
КонецЦикла;
тдКонтрагенты.ЗакончитьГруппуСтрок();
КонецЕсли;
КонецЦикла;
КонецЦикла;
Если тдЭлементФормы=Неопределено Тогда
// Если предстоит выводить отчет в отдельном окне, то проверить : есть ли задвоения ?
// Если задвоений нет, то лишнее окно на экран выводить не следует
Если нЗадвоенийВсего>0 Тогда
тдКонтрагенты.Показать("Отчет о задвоенных контрагентах");
Иначе
Сообщить("Нет задвоенных контрагентов !");
КонецЕсли;
Иначе
// Окно для вывода печати содержится на дополнительной закладке.
// По умолчанию, туда и так выводится отчет и сразу показывается информация.
КонецЕсли;
Возврат лУникальностьПоИНН;
КонецФункции